Arduino - Sensor de umidade

Nesta seção, aprenderemos como fazer a interface de nossa placa Arduino com diferentes sensores. Discutiremos os seguintes sensores -

Sensor de umidade (DHT22)
Sensor de temperatura (LM35)
Sensor detector de água (Simple Water Trigger)
SENSOR PIR
SENSOR ULTRASÔNICO
GPS

Sensor de umidade (DHT22)

O DHT-22 (também denominado AM2302) é um sensor de saída digital, umidade relativa e temperatura. Ele usa um sensor de umidade capacitivo e um termistor para medir o ar circundante e envia um sinal digital no pino de dados.

Neste exemplo, você aprenderá como usar este sensor com o Arduino UNO. A temperatura e a umidade da sala serão impressas no monitor serial.

O Sensor DHT-22

As conexões são simples. O primeiro pino à esquerda para alimentação de 3-5 V, o segundo pino para o pino de entrada de dados e o pino mais à direita para o aterramento.

Detalhes técnicos

Power - 3-5V
Max Current - 2,5mA
Humidity - 0-100%, precisão de 2-5%
Temperature - 40 a 80 ° C, precisão de ± 0,5 ° C

Componentes necessários

Você precisará dos seguintes componentes -

1 × breadboard
1 × Arduino Uno R3
1 × DHT22
1 × 10K ohm resistor

Procedimento

Siga o diagrama do circuito e conecte os componentes na placa de ensaio, conforme mostrado na imagem abaixo.

Esboço

Abra o software Arduino IDE em seu computador. A codificação na linguagem Arduino controlará seu circuito. Abra um novo arquivo de esboço clicando em Novo.

Código Arduino

// Example testing sketch for various DHT humidity/temperature sensors

#include "DHT.h"
#define DHTPIN 2 // what digital pin we're connected to
// Uncomment whatever type you're using!
//#define DHTTYPE DHT11 // DHT 11
#define DHTTYPE DHT22 // DHT 22 (AM2302), AM2321
//#define DHTTYPE DHT21 // DHT 21 (AM2301)
// Connect pin 1 (on the left) of the sensor to +5V
// NOTE: If using a board with 3.3V logic like an Arduino Due connect pin 1
// to 3.3V instead of 5V!
// Connect pin 2 of the sensor to whatever your DHTPIN is
// Connect pin 4 (on the right) of the sensor to GROUND
// Connect a 10K resistor from pin 2 (data) to pin 1 (power) of the sensor
// Initialize DHT sensor.
// Note that older versions of this library took an optional third parameter to
// tweak the timings for faster processors. This parameter is no longer needed
// as the current DHT reading algorithm adjusts itself to work on faster procs.
DHT dht(DHTPIN, DHTTYPE);

void setup() {
   Serial.begin(9600);
   Serial.println("DHTxx test!");
   dht.begin();
}

void loop() {
   delay(2000); // Wait a few seconds between measurements
   float h = dht.readHumidity();
   // Reading temperature or humidity takes about 250 milliseconds!
   float t = dht.readTemperature();
   // Read temperature as Celsius (the default)
   float f = dht.readTemperature(true);
   // Read temperature as Fahrenheit (isFahrenheit = true)
   // Check if any reads failed and exit early (to try again).
   if (isnan(h) || isnan(t) || isnan(f)) {
      Serial.println("Failed to read from DHT sensor!");
      return;
   }
   
   // Compute heat index in Fahrenheit (the default)
   float hif = dht.computeHeatIndex(f, h);
   // Compute heat index in Celsius (isFahreheit = false)
   float hic = dht.computeHeatIndex(t, h, false);
   Serial.print ("Humidity: ");
   Serial.print (h);
   Serial.print (" %\t");
   Serial.print ("Temperature: ");
   Serial.print (t);
   Serial.print (" *C ");
   Serial.print (f);
   Serial.print (" *F\t");
   Serial.print ("Heat index: ");
   Serial.print (hic);
   Serial.print (" *C ");
   Serial.print (hif);
   Serial.println (" *F");
}

Código a ser anotado

O sensor DHT22 possui quatro terminais (V _cc , DATA, NC, GND), que são conectados à placa da seguinte forma -

PIN de DADOS para o pino número 2 do Arduino
Pino V _cc para 5 volts da placa Arduino
Pino GND ao solo da placa Arduino
Precisamos conectar o resistor de 10k ohm (pull up resistor) entre o DATA e o pino V _cc

Assim que as conexões de hardware forem feitas, você precisa adicionar a biblioteca DHT22 ao seu arquivo de biblioteca do Arduino conforme descrito anteriormente.

Resultado

Você verá a tela de temperatura e umidade no monitor da porta serial, que é atualizado a cada 2 segundos.

↰ Previous page Next page ↱