Linguagem Q - Consultas Funcionais

As consultas funcionais (dinâmicas) permitem especificar nomes de colunas como símbolos para colunas q-sql select / exec / delete típicas. É muito útil quando queremos especificar nomes de coluna dinamicamente.

As formas funcionais são -

?[t;c;b;a]    / for select
![t;c;b;a]    / for update

Onde

  • t é uma mesa;

  • a é um dicionário de agregados;

  • bo by-frase; e

  • c é uma lista de restrições.

Nota -

  • Todos q entidades em a, be c deve ser referenciado por nome, ou seja, como símbolos contendo os nomes das entidades.

  • As formas sintáticas de seleção e atualização são analisadas em suas formas funcionais equivalentes pelo q intérprete, portanto, não há diferença de desempenho entre os dois formulários.

Seleção funcional

O seguinte bloco de código mostra como usar functional select -

q)t:([]n:`ibm`msft`samsung`apple;p:40 38 45 54)

q)t

    n       p
-------------------
   ibm     40
   msft    38
 samsung   45
  apple    54

q)select m:max p,s:sum p by name:n from t where p>36, n in `ibm`msft`apple

  name |   m   s
------ | ---------
 apple |  54  54
 ibm   |  40  40
 msft  |  38  38

Exemplo 1

Vamos começar com o caso mais fácil, a versão funcional do “select from t” será parecido com -

q)?[t;();0b;()]     / select from t

    n      p
-----------------
   ibm    40
   msft   38
 samsung  45
  apple   54

Exemplo 2

No exemplo a seguir, usamos a função enlist para criar singletons para garantir que as entidades apropriadas sejam listas.

q)wherecon: enlist (>;`p;40)

q)?[`t;wherecon;0b;()] / select from t where p > 40

    n      p
----------------
 samsung  45
  apple   54

Exemplo 3

q)groupby: enlist[`p] ! enlist `p

q)selcols: enlist [`n]!enlist `n

q)?[ `t;(); groupby;selcols]        / select n by p from t

   p  |    n
----- | -------
  38  |  msft
  40  |  ibm
  45  | samsung
  54  | apple

Exec Funcional

A forma funcional do exec é uma forma simplificada de select.

q)?[t;();();`n]                / exec n from t (functional form of exec)
`ibm`msft`samsung`apple

q)?[t;();`n;`p]                / exec p by n from t (functional exec)

apple   | 54
ibm     | 40
msft    | 38
samsung | 45

Atualização Funcional

A forma funcional de atualização é completamente análoga à de select. No exemplo a seguir, o uso de enlist é para criar singletons, para garantir que as entidades de entrada sejam listas.

q)c:enlist (>;`p;0)

q)b: (enlist `n)!enlist `n

q)a: (enlist `p) ! enlist (max;`p)

q)![t;c;b;a]

   n      p
-------------
  ibm    40
  msft   38
 samsung 45
 apple   54

Exclusão funcional

A exclusão funcional é uma forma simplificada de atualização funcional. Sua sintaxe é a seguinte -

![t;c;0b;a]        / t is a table, c is a list of where constraints, a is a
                   / list of column names

Vamos agora dar um exemplo para mostrar como funciona a exclusão funcional -

q)![t; enlist (=;`p; 40); 0b;`symbol$()]
                                          / delete from t where p = 40
   n       p
---------------
  msft    38
 samsung  45
  apple   54